// Bunte Bälle bewegen sich
// Reflexion an den Wänden

int ANZAHL = 250;
Ball[]  balls;         

void setup() {
    size(200,200);
    balls = new Ball[ANZAHL];
    for (int i=0; i<ANZAHL; i++) balls[i] = new Ball(i);
    frameRate(20);
    smooth();
    background(0);
}

void draw() {
    fill(0,20);
    rect(0,0,width,height);
    for (int i=0; i<ANZAHL; i++) balls[i].move();    
    for (int i=0; i<ANZAHL; i++) balls[i].paint();    
}

////////////////////////////////////////////////////////////
//
class Ball {
    float x,y;      // Ort
    float vx,vy;    // Geschwindigkeit
    float r;        // Radius
    color col;      // Farbe  
    
    Ball(int number) {            
        x = width/2.0;
        y = height/2.0;
        vx = random(-2,2);
        vy = random(-2,2);
        r = random(5,20);
        colorMode(HSB);
        col = color(random(0,256),255,255,random(50,250));
        paint();
    }

    // das Ballobjekt zeichnen
    void paint() {
        noStroke();
        fill(col);
        ellipseMode(RADIUS);
        ellipse(x,y,r,r);
    } 
    
    // den Ball bewegen, exakte Reflexion 
    // die Spiegelung von z an D ist D-(z-D) = 2D-z
    void move() {          
        float xnew = x+vx;    // neue Position testen
        float ynew = y+vy;
        
        // wenn der Ball innerhalb bleibt, ist dies die neue Position
        if (xnew>=0 && xnew<width && ynew>=0 && ynew<height) {
          x = xnew;
          y = ynew;
          return;         
        }  
        
        // falls eine Wand überschritten wird, reflektieren
        if (xnew<0) {
            x = -x;
            y = ynew;
            vx = -vx;
        }
        if (xnew>=width) {
            x = 2*(width)-x;
            y = ynew;
            vx = -vx;
        }
        if (ynew<r) {
            x = xnew;
            y = -y;
            vy = -vy;
        }
        if (ynew>=height) {
            x = xnew;
            y = 2*(height)-y;
            vy = -vy;
        }
    }
}
//
////////////////////////////////////////////////////////////