// Bunte Bälle bewegen sich
// Reflexion an den Wänden

int ANZAHL = 10;
Ball[]  balls;         

void setup() {
    size(200,200);
    balls = new Ball[ANZAHL];
    for (int i=0; i<ANZAHL; i++) balls[i] = new Ball(i);
    frameRate(30);
    smooth();
}

void draw() {
    background(0);
    for (int i=0; i<ANZAHL; i++) balls[i].move();    
    for (int i=0; i<ANZAHL; i++) balls[i].paint();    
}

////////////////////////////////////////////////////////////
//
class Ball {
    float x,y;      // Ort
    float vx,vy;    // Geschwindigkeit
    float r;        // Radius
    color col;      // Farbe  
    
    Ball(int number) {            
        x = width/2.0;
        y = height/2.0;
        vx = random(-4,4);
        vy = random(-4,4);
        r = random(5,30);
        colorMode(HSB);
        col = color(random(0,256),255,255);
        paint();
    }

    // das Ballobjekt zeichnen
    void paint() {
        noStroke();
        fill(col);
        ellipseMode(RADIUS);
        ellipse(x,y,r,r);
    } 
    
    // den Ball bewegen, exakte Reflexion 
    // die Spiegelung von z an D ist D-(z-D) = 2D-z
    void move() {          
        float xnew = x+vx;    // neue Position testen
        float ynew = y+vy;
        
        // wenn der Ball innerhalb bleibt, ist dies die neue Position
        if (xnew>=0+r && xnew<width-r && ynew>=0+r && ynew<height-r) {
          x = xnew;
          y = ynew;
          return;         
        }  
        
        // falls eine Wand überschritten wird, reflektieren
        if (xnew<0+r) {
            x = 2*r-x;
            y = ynew;
            vx = -vx;
        }
        if (xnew>=width-r) {
            x = 2*(width-r)-x;
            y = ynew;
            vx = -vx;
        }
        if (ynew<0+r) {
            x = xnew;
            y = 2*r-y;
            vy = -vy;
        }
        if (ynew>=height-r) {
            x = xnew;
            y = 2*(height-r)-y;
            vy = -vy;
        }
    }
}
//
////////////////////////////////////////////////////////////