Der Spiegelwürfel

Wir basteln aus drei bunten Stäben und einem kleinen Würfel ein Achsenkreuz

union
{ 
 // ein Würfel als Verbindungsstück 
 box {-3, 3 pigment { rgb <1,1,1>*2}} 
 // drei Stäbe 
 box {<-1, -1, -20 >< 1, 1, 20 > pigment {rgb <1,0,0>*2}} 
 box {<-1, -20, -1 >< 1, 20, 1 > pigment {rgb <0,1,0>*2}}
 box {<-20, -1, -1 >< 20, 1, 1 > pigment {rgb <0,0,1>*2}}
 
}

Das sieht so aus:

Nun stellen wir dieses Kreuz in eine Schachtel. Zur Veranschaulichung habe ich diese transparent gemacht:

Jetzt stellen wir die Kamera in den Würfel hinein, definieren die  Schachtel als hohl und machen ihre Wände zu perfekten Spiegeln. Damit erhalten wir jede Menge Reflexionen und die Darstellung eines unendlichen periodischen 3D-Raumes

Um den Effekt noch dramatischer zu gestalten, färben wir alles in grellem weiß, lassen keine Schatten werfen und rendern mit Antialiasing. Das endgültige Werk wird dann zu

// ein unendlicher kubischer Raum:
// realisiert durch Spiegelwände 

// ausreichend viele Reflexionen zulassen 
global_settings { max_trace_level 50 }
 
// eine Lichtquelle 
light_source { <-10,-7,-2 > <1,1,1>
 shadowless // sie wirft keine Schatten
}


box { -20, 20 // eine Spiegelschachtel
 finish {
 reflection 1 // 100% Reflektion
 ambient 0 // keine Eigenfarbe
 }
 hollow // ohne Inneres, nur Oberfläche 

 rotate 20 // leicht verdrehte Ansicht
 translate 10 
}
 
// ein Achsenkreuz im Zentrum 
union
{ 
 box {-3, 3} // Würfel als Verbindungsstück
 // drei Stäbe 
 box {<-1, -1, -20 >< 1, 1, 20 >} 
 box {<-1, -20, -1 >< 1, 20, 1 >}
 box {<-20, -1, -1 >< 20, 1, 1 >}
 
 rotate 20 // leicht verdrehte Ansicht
 translate 10
 
 pigment {rgb 2} // extrem helles weiß
}