Heightfield City 1

Das Muster cells erzeugt lauter 1x1 Quadrate unterschiedlicher Graustufe. Dies können wir als 'interne Bitmap' verwenden. Hier eine derart gemusterte Ebene:

Verwenden wir diese Farbinformationen als Höhenwerte in einem heightfield, wachsen die Quadrate zu Prismen heran.

Nehmen wir stimmungsvolles Streulicht (mit Farbfilterung) dazu, befinden wir uns über einer futuristisch anmutenden Wolkenkratzer-Stadt. 

// Heightfield City 1 
 
camera { 
   location <10,7,0> 
   look_at <0,1,0>
}

// gewöhnliche Lichtquelle von links
light_source { <-140,200,300> rgb 1.5}   
// schatztenloses Füll-Licht von rechts
light_source { <140,200,-300> rgb 0.9 shadowless}

// Heightfield mit cells-pigment als 
// interner bitmap auf <0,0,0> bis <<1,1,0>
height_field { 
    function 2000,2000 { // Auflösung
	pigment {
	    cells 
	    color_map {
	       [0 rgb 0]
	       [1 rgb 1]
	    }
	    scale .004
	}
     }
     translate -0.5 
     scale <125,10,125> 
     pigment { rgb 1 }
}

// stimmungsvolles Streulicht
plane{y,5 
    pigment { rgbt <0,0,0,1> }
    hollow 
    interior { 
	media {            
	    // Typ 1 isotrop
	    scattering { 
	        1,         
	        rgb <0.25,0.5,1>/4
	    }
	}
    }
}